plugins {
    id "fabric-loom" version "${legacy_loom_version}" apply false
    id "net.fabricmc.fabric-loom" version "${loom_version}" apply false
}

apply plugin: project.minecraft_version.startsWith("26.") ? "net.fabricmc.fabric-loom" : "fabric-loom"

version = project.mod_version
group = project.maven_group

base {
    archivesName = "${project.archives_base_name}-${project.minecraft_version}"
}

repositories {
    maven { url = "https://maven.terraformersmc.com/releases/" }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    if (project.minecraft_version.startsWith("26.")) {
        implementation "net.fabricmc:fabric-loader:${project.loader_version}"
        implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"
    } else {
        mappings loom.officialMojangMappings()
        modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
        modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"
    }
    if (project.minecraft_version.startsWith("26.")) {
        compileOnly "com.terraformersmc:modmenu:${project.modmenu_version}"
    } else {
        modCompileOnly "com.terraformersmc:modmenu:${project.modmenu_version}"
    }
    testImplementation "org.junit.jupiter:junit-jupiter:5.10.2"
    testRuntimeOnly "org.junit.platform:junit-platform-launcher"
}

sourceSets.main.java.srcDir(
        project.minecraft_version.startsWith("26.")
                ? "src/versions/modern/java"
                : "src/versions/legacy/java"
)

tasks.withType(Test).configureEach {
    useJUnitPlatform()
}

processResources {
    inputs.property "version", project.version
    inputs.property "minecraft_version", project.minecraft_version

    filesMatching("fabric.mod.json") {
        expand "version": project.version, "minecraft_version": project.minecraft_version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = project.java_version.toInteger()
}

java {
    withSourcesJar()
    sourceCompatibility = JavaVersion.toVersion(project.java_version)
    targetCompatibility = JavaVersion.toVersion(project.java_version)
}